3. Zusammengesetzte Datentypen

3.1 Daten bündeln mit Records

Erinnern Sie sich an unseren Versuch aus dem letzten Teilkapitel, Kalenderdaten in als Tripel darzustellen, also beispielsweise (3, 10, 2023). Das Problem ist, dass die einzelnen Positionen (erste, zweite, dritte) nicht benannt sind und andere Entwickler nicht wissen, ob Sie die Daten im Format (day, month, year) oder (month, day, year) oder (year, month, day) repräsentieren. Besser geht es mit Records:

firstDayOfLectures = {day = 4, month = 10, year = 2023}

Jetzt kann es keine Verwechslungen mehr geben. Was wir gerade getan haben, ist, dem Bezeichner firstDayOfLectures einen Wert mit einem Record-Typ zugewiesen zu haben. Records sind im Prinzip nichts wirklich Anderes als Tupel, nur dass wir für die einzelnen Einträge selbst Namen vergeben können, statt sie als erste Koordinate und zweite Koordinate zu bezeichnen. Öffnen Sie mit Ihrem Code-Editor eine neue Datei und speichern Sie sie als PP/elm/src/Date.elm ab. Kopieren Sie folgenden Code hinein:

module Date exposing (..)


type alias Date =
    { day : Int
    , month : Int
    , year : Int
    }


wiedervereinigung : Date
wiedervereinigung =
    { day = 3, month = 10, year = 1990 }

Die Zeilen 4-8 zeigen Ihnen, wie wir einen neuen Record-Datentyp definieren. Der Name für den neuen Typ, hier Code, muss zwingend mit einem Großbuchstaben beginnen. Die Konvention, dass Typen mit Großbuchstaben und Bezeichner mit Kleinbuchstaben beginnen, gilt auch in anderen Sprachen wie Java. In Elm ist es aber Teil der Syntax, d.h. Ihr Programm wird nicht starten, wenn Sie sich nicht an diese Konvention halten. In Zeile 11-13 konstruieren wir einen Ausdruck vom Typ Date, indem wir allen Einträgen Werte zuweisen (hier muss jeder Wert ein Int sein).

Jetzt wissen Sie, wie man ein Record-Objekt konstruiert (Zeile 11-13). Als nächstes lernen Sie, wie man auf die einzelnen Felder zugreift. Öffnen Sie Elm im Repl-Modus:

H:\PP\elm\> elm repl
import Date exposing (..)
wiedervereinigung.month
10 : Int

Auf die einzelnen Felder greifen Sie also genauso zu wie in Java. Wenn Sie aus einem Record-Objekt ein neues bauen wollen, dass sich in einigen wenigen Feldern unterscheidet, also beispielsweise das Feld year auf 2023 setzen, dann geht das so:

einheitstag2023 = {wiedervereinigung | year = 2023}

Alternativ können Sie natürlich auch

einheitstag2023 = {year = 2023, month = wiedervereinigung.month, day = wiedervereinigung.day}

schreiben, also jedes Feld "per Hand" kopieren.

Geometrie

Für Punkte im zweidimensionalen Raum, gerichtete Geraden und Dreiecke legen wir nun Record-Typen an. Legen Sie mit Ihrem Code-Editor eine neue Datei an und speichern Sie sie unter PP/elm/src/Geometry.elm. Kopieren Sie folgenden Code hinein:

module Geometry exposing (..)


type alias Vector =
    { x : Float
    , y : Float
    }


type alias DirectedLine =
    { from : Vector
    , to : Vector
    }


type alias Triangle =
    { a : Vector, b : Vector, c : Vector }

All dies hätten wir auch mit Tupeln geschafft. Allerdings ist es nun klarer, was womit gemeint ist (und später wird der Unterschied noch klarer). Ich zeige Ihnen nun, wie Sie Records anlegen und auf die einzelnen Einträge zugreifen:

v : Vector                        
v = {x = 0.4, y = 0.8} -- so initialisieren Sie einen Record
v.x -- so greifen Sie auf die Einträge zu; wie in Java
0.4 : Float

Als nächstes implementieren wir die Funktion rotateVector. Dies haben Sie ja hoffentlich in Kapitel 2.7 bereits getan, allerdings mit Tupeln und nicht mit Records.

rotateVector : Float -> Vector -> Vector
rotateVector angle v =
    let
        sinAngle : Float
        sinAngle =
            sin angle

        cosAngle : Float
        cosAngle =
            cos angle
    in
    { x = v.x * cosAngle - v.y * sinAngle, y = v.x * sinAngle + v.y * cosAngle }                        
                    

leftRightOrOnLine : DirectedLine -> Vector -> Int

insideTriangle : Triangle -> Vector -> Bool 

Heterogene Daten

Nur damit die bisherigen Beispiele Sie nicht glauben machen, alle Felder eines Record-Typs müssten die gleichen Typen haben (Bei Kalenderdaten waren alle Felder Int; bei unseren Vektoren waren sie alle Float): dies ist sicherlich nicht der Fall. Sie dürfen gerne heterogene Records erstellen (das ist sogar der Regelfall), wie beispielsweise

type alias Resident =
    { firstname : String
    , lastname : String
    , dateOfBirth : Date
    , street : String
    , houseNumber : Int
    , city : String
    , zipCode : Int
    , taxNumber : Int
    , married : Bool
    }

Das offensichtlichste Problem ist, dass houseNumber ein Int ist. Denn wie repräsentieren Sie dann Adressen wie Bahnhofstraße 2a? Was tun Sie mit Ihrer Software, wenn die deutsche Post plötzlich beginnt, Buchstaben in die Postleitzahlen (zipCode) zu integrieren?

Auf die Frage, ob man Daten als String oder Int darstellen sollte, hat Phil Scovis auf Quora eine wunderbare Antwort gegeben: